mirror of
https://github.com/fish-shell/fish-shell.git
synced 2024-11-23 12:52:29 +08:00
11a60c8374
I hate doing this but I am tired of touching a fish script as part of some change and having `make style` radically change it. Which makes editing fish scripts more painful than it needs to be. It is time to do a wholesale reformatting of these scripts to conform to the documented style as implemented by the `fish_indent` program.
49 lines
1.3 KiB
Fish
49 lines
1.3 KiB
Fish
# If seq is not installed, then define a function that invokes __fish_fallback_seq
|
|
# We can't call type here because that also calls seq
|
|
|
|
if not command -s seq >/dev/null
|
|
# No seq command
|
|
function seq --description "Print sequences of numbers"
|
|
__fish_fallback_seq $argv
|
|
end
|
|
|
|
function __fish_fallback_seq --description "Fallback implementation of the seq command"
|
|
|
|
set -l from 1
|
|
set -l step 1
|
|
set -l to 1
|
|
|
|
switch (count $argv)
|
|
case 1
|
|
set to $argv[1]
|
|
|
|
case 2
|
|
set from $argv[1]
|
|
set to $argv[2]
|
|
|
|
case 3
|
|
set from $argv[1]
|
|
set step $argv[2]
|
|
set to $argv[3]
|
|
|
|
case '*'
|
|
printf (_ "%s: Expected 1, 2 or 3 arguments, got %d\n") seq (count $argv)
|
|
return 1
|
|
|
|
end
|
|
|
|
for i in $from $step $to
|
|
if not echo $i | grep -E '^-?[0-9]*([0-9]*|\.[0-9]+)$' >/dev/null
|
|
printf (_ "%s: '%s' is not a number\n") seq $i
|
|
return 1
|
|
end
|
|
end
|
|
|
|
if [ $step -ge 0 ]
|
|
echo "for( i=$from; i<=$to ; i+=$step ) i;" | bc
|
|
else
|
|
echo "for( i=$from; i>=$to ; i+=$step ) i;" | bc
|
|
end
|
|
end
|
|
end
|