mirror of
https://github.com/fish-shell/fish-shell.git
synced 2024-11-23 03:54:04 +08:00
07543ff881
Because we reload changed function files, a common issue on upgrading
to 3.4.0 is that fish_title causes errors.
So we simply use the oldschool syntax.
(cherry picked from commit c5a8764db1)
22 lines
919 B
Fish
22 lines
919 B
Fish
function fish_title
|
|
# emacs' "term" is basically the only term that can't handle it.
|
|
if not set -q INSIDE_EMACS; or string match -vq '*,term:*' -- $INSIDE_EMACS
|
|
# If we're connected via ssh, we print the hostname.
|
|
set -l ssh
|
|
set -q SSH_TTY
|
|
and set ssh "["(prompt_hostname | string sub -l 10 | string collect)"]"
|
|
# An override for the current command is passed as the first parameter.
|
|
# This is used by `fg` to show the true process name, among others.
|
|
if set -q argv[1]
|
|
echo -- $ssh (string sub -l 20 -- $argv[1]) (prompt_pwd -d 1 -D 1)
|
|
else
|
|
# Don't print "fish" because it's redundant
|
|
set -l command (status current-command)
|
|
if test "$command" = fish
|
|
set command
|
|
end
|
|
echo -- $ssh (string sub -l 20 -- $command) (prompt_pwd -d 1 -D 1)
|
|
end
|
|
end
|
|
end
|