mirror of
https://github.com/fish-shell/fish-shell.git
synced 2024-12-01 23:24:21 +08:00
a605bcb830
This commit lets you check the manpage for a leading command by moving
the cursor over it, matching the behavior of tab complete.
It also lets you select the man page for the base of a two-part command
like `string match`.
The additional regex case is added because
`commandline -t` returns an empty string when the cursor is after a
space, e.g. at the end of 'sudo ', which the later checks don't handle.
This diagram shows the manpage picked for different cursor positions:
> sudo -Es time git commit -m foo
+-------++---++--++------------+
| || || || |
| || || |+------------+
| || || | git-commit
| || |+--+
| || | git
| |+---+
| | time
+-------+
sudo
39 lines
1.5 KiB
Fish
39 lines
1.5 KiB
Fish
function __fish_man_page
|
|
# Get all commandline tokens not starting with "-", up to and including the cursor's
|
|
set -l args (string match -rv '^-|^$' -- (commandline -cpo && commandline -t))
|
|
|
|
# If commandline is empty, exit.
|
|
if not set -q args[1]
|
|
printf \a
|
|
return
|
|
end
|
|
|
|
# Skip leading commands and display the manpage of following command
|
|
while set -q args[2]
|
|
and string match -qr -- '^(and|begin|builtin|caffeinate|command|doas|entr|env|exec|if|mosh|nice|not|or|pipenv|prime-run|setsid|sudo|systemd-nspawn|time|watch|while|xargs|.*=.*)$' $args[1]
|
|
set -e args[1]
|
|
end
|
|
|
|
# If there are at least two tokens not starting with "-", the second one might be a subcommand.
|
|
# Try "man first-second" and fall back to "man first" if that doesn't work out.
|
|
set -l maincmd (basename $args[1])
|
|
# HACK: If stderr is not attached to a terminal `less` (the default pager)
|
|
# wouldn't use the alternate screen.
|
|
# But since we don't know what pager it is, and because `man` is totally underspecified,
|
|
# the best we can do is to *try* the man page, and assume that `man` will return false if it fails.
|
|
# See #7863.
|
|
if set -q args[2]
|
|
and not string match -q -- '*/*' $args[2]
|
|
and man "$maincmd-$args[2]" &>/dev/null
|
|
man "$maincmd-$args[2]"
|
|
else
|
|
if man "$maincmd" &>/dev/null
|
|
man "$maincmd"
|
|
else
|
|
printf \a
|
|
end
|
|
end
|
|
|
|
commandline -f repaint
|
|
end
|