mirror of
https://github.com/fish-shell/fish-shell.git
synced 2024-12-03 16:44:00 +08:00
55bc6a27c6
Commit5d135d555(prompts: fix pipestatus for jobs prefixed with "not") introduced a backwards compatibility hack about adding an optional argument to __fish_print_pipestatus. This hack would break downgrading to fish 3.1.2 if the user copied the new prompt to their config - they would get a backtrace on every prompt which is arguably worse than the patch's minor improvement. This does away with the error trace - old fish just won't show the fancy new pipestatus on `not true`. Implemented by passing the last $status as the poor man's kwarg, which works since 3.1.0 (9b86d5dd1Export all local exported variables in a new scope). The prompts don't work with fish 3.0.0 or older; downgrading does not seem too important in general but I think this patch is an okay simplification.
23 lines
1.1 KiB
Fish
23 lines
1.1 KiB
Fish
# name: Informative
|
|
# http://michal.karzynski.pl/blog/2009/11/19/my-informative-shell-prompt/
|
|
|
|
function fish_prompt --description 'Informative prompt'
|
|
#Save the return status of the previous command
|
|
set -l last_pipestatus $pipestatus
|
|
set -lx __fish_last_status $status # Export for __fish_print_pipestatus.
|
|
|
|
if functions -q fish_is_root_user; and fish_is_root_user
|
|
printf '%s@%s %s%s%s# ' $USER (prompt_hostname) (set -q fish_color_cwd_root
|
|
and set_color $fish_color_cwd_root
|
|
or set_color $fish_color_cwd) \
|
|
(prompt_pwd) (set_color normal)
|
|
else
|
|
set -l pipestatus_string (__fish_print_pipestatus "[" "] " "|" (set_color $fish_color_status) \
|
|
(set_color --bold $fish_color_status) $last_pipestatus)
|
|
|
|
printf '[%s] %s%s@%s %s%s %s%s%s \f\r> ' (date "+%H:%M:%S") (set_color brblue) \
|
|
$USER (prompt_hostname) (set_color $fish_color_cwd) $PWD $pipestatus_string \
|
|
(set_color normal)
|
|
end
|
|
end
|