mirror of
https://github.com/ohmyzsh/ohmyzsh.git
synced 2024-11-22 22:06:09 +08:00
98 lines
2.8 KiB
Bash
98 lines
2.8 KiB
Bash
# Set terminal window and tab/icon title
|
|
#
|
|
# usage: title short_tab_title [long_window_title]
|
|
#
|
|
# See: http://www.faqs.org/docs/Linux-mini/Xterm-Title.html#ss3.1
|
|
# Fully supports screen, iterm, and probably most modern xterm and rxvt
|
|
# (In screen, only short_tab_title is used)
|
|
# Limited support for Apple Terminal (Terminal can't set window and tab separately)
|
|
function title {
|
|
emulate -L zsh
|
|
setopt prompt_subst
|
|
|
|
[[ "$EMACS" == *term* ]] && return
|
|
|
|
# if $2 is unset use $1 as default
|
|
# if it is set and empty, leave it as is
|
|
: ${2=$1}
|
|
|
|
case "$TERM" in
|
|
cygwin|xterm*|putty*|rxvt*|ansi)
|
|
print -Pn "\e]2;$2:q\a" # set window name
|
|
print -Pn "\e]1;$1:q\a" # set tab name
|
|
;;
|
|
screen*)
|
|
print -Pn "\ek$1:q\e\\" # set screen hardstatus
|
|
;;
|
|
*)
|
|
if [[ "$TERM_PROGRAM" == "iTerm.app" ]]; then
|
|
print -Pn "\e]2;$2:q\a" # set window name
|
|
print -Pn "\e]1;$1:q\a" # set tab name
|
|
fi
|
|
;;
|
|
esac
|
|
}
|
|
|
|
ZSH_THEME_TERM_TAB_TITLE_IDLE="%15<..<%~%<<" #15 char left truncated PWD
|
|
ZSH_THEME_TERM_TITLE_IDLE="%n@%m: %~"
|
|
# Avoid duplication of directory in terminals with independent dir display
|
|
if [[ $TERM_PROGRAM == Apple_Terminal ]]; then
|
|
ZSH_THEME_TERM_TITLE_IDLE="%n@%m"
|
|
fi
|
|
|
|
# Runs before showing the prompt
|
|
function omz_termsupport_precmd {
|
|
emulate -L zsh
|
|
if [[ $DISABLE_AUTO_TITLE == true ]]; then
|
|
return
|
|
fi
|
|
|
|
title $ZSH_THEME_TERM_TAB_TITLE_IDLE $ZSH_THEME_TERM_TITLE_IDLE
|
|
}
|
|
|
|
# Runs before executing the command
|
|
function omz_termsupport_preexec {
|
|
emulate -L zsh
|
|
if [[ $DISABLE_AUTO_TITLE == true ]]; then
|
|
return
|
|
fi
|
|
|
|
setopt extended_glob
|
|
|
|
# cmd name only, or if this is sudo or ssh, the next cmd
|
|
local CMD=${1[(wr)^(*=*|sudo|ssh|mosh|rake|-*)]:gs/%/%%}
|
|
local LINE="${2:gs/%/%%}"
|
|
|
|
title '$CMD' '%100>...>$LINE%<<'
|
|
}
|
|
|
|
precmd_functions+=(omz_termsupport_precmd)
|
|
preexec_functions+=(omz_termsupport_preexec)
|
|
|
|
|
|
# Keep Apple Terminal.app's current working directory updated
|
|
# Based on this answer: http://superuser.com/a/315029
|
|
# With extra fixes to handle multibyte chars and non-UTF-8 locales
|
|
|
|
if [[ "$TERM_PROGRAM" == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]]; then
|
|
|
|
# Emits the control sequence to notify Terminal.app of the cwd
|
|
function update_terminalapp_cwd() {
|
|
emulate -L zsh
|
|
# Identify the directory using a "file:" scheme URL, including
|
|
# the host name to disambiguate local vs. remote paths.
|
|
|
|
# Percent-encode the pathname.
|
|
local URL_PATH="$(omz_urlencode -P $PWD)"
|
|
[[ $? != 0 ]] && return 1
|
|
local PWD_URL="file://$HOST$URL_PATH"
|
|
# Undocumented Terminal.app-specific control sequence
|
|
printf '\e]7;%s\a' $PWD_URL
|
|
}
|
|
|
|
# Use a precmd hook instead of a chpwd hook to avoid contaminating output
|
|
precmd_functions+=(update_terminalapp_cwd)
|
|
# Run once to get initial cwd set
|
|
update_terminalapp_cwd
|
|
fi
|