mirror of
https://github.com/ohmyzsh/ohmyzsh.git
synced 2024-12-02 07:53:39 +08:00
51 lines
1.7 KiB
Bash
51 lines
1.7 KiB
Bash
#usage: title short_tab_title looooooooooooooooooooooggggggg_windows_title
|
|
#http://www.faqs.org/docs/Linux-mini/Xterm-Title.html#ss3.1
|
|
#Fully support screen, iterm, and probably most modern xterm and rxvt
|
|
function title {
|
|
if [[ "$DISABLE_AUTO_TITLE" == "true" ]] || [[ "$EMACS" == *term* ]]; then
|
|
return
|
|
fi
|
|
if [[ "$TERM" == screen* ]]; then
|
|
print -Pn "\ek$1:q\e\\" #set screen hardstatus, usually truncated at 20 chars
|
|
elif [[ "$TERM" == xterm* ]] || [[ $TERM == rxvt* ]] || [[ $TERM == ansi ]] || [[ "$TERM_PROGRAM" == "iTerm.app" ]]; then
|
|
print -Pn "\e]2;$2:q\a" #set window name
|
|
print -Pn "\e]1;$1:q\a" #set icon (=tab) name
|
|
fi
|
|
}
|
|
|
|
ZSH_THEME_TERM_TAB_TITLE_IDLE="%15<..<%~%<<" #15 char left truncated PWD
|
|
ZSH_THEME_TERM_TITLE_IDLE="%n@%m: %~"
|
|
|
|
#Appears when you have the prompt
|
|
function omz_termsupport_precmd {
|
|
title $ZSH_THEME_TERM_TAB_TITLE_IDLE $ZSH_THEME_TERM_TITLE_IDLE
|
|
}
|
|
|
|
#Appears at the beginning of (and during) of command execution
|
|
function omz_termsupport_preexec {
|
|
emulate -L zsh
|
|
setopt extended_glob
|
|
|
|
# cmd name only, or if this is sudo or ssh, the next cmd
|
|
local CMD=${1[(wr)^(*=*|sudo|ssh|rake|-*)]:gs/%/%%}
|
|
local LINE="${2:gs/%/%%}"
|
|
|
|
title '$CMD' '%100>...>$LINE%<<'
|
|
}
|
|
|
|
#Appears each time pwd is changed
|
|
function omz_termsupport_chpwd {
|
|
#Notify Terminal.app of current directory using undocumented OSC sequence
|
|
#found in OS X 10.10's /etc/bashrc
|
|
if [[ $TERM_PROGRAM == Apple_Terminal ]] && [[ -z $INSIDE_EMACS ]]; then
|
|
local PWD_URL="file://$HOSTNAME${PWD// /%20}"
|
|
printf '\e]7;%s\a' "$PWD_URL"
|
|
fi
|
|
}
|
|
#Fire it once so the pwd is set properly upon shell startup
|
|
omz_termsupport_chpwd
|
|
|
|
precmd_functions+=(omz_termsupport_precmd)
|
|
preexec_functions+=(omz_termsupport_preexec)
|
|
chpwd_functions+=(omz_termsupport_chpwd)
|