mirror of
https://github.com/vim-airline/vim-airline-themes.git
synced 2024-12-12 13:23:35 +08:00
101 lines
4.4 KiB
VimL
101 lines
4.4 KiB
VimL
" MIT license. Copyright (c) 2013 Bailey Ling.
|
||
" vim: ts=2 sts=2 sw=2 fdm=indent
|
||
|
||
if &cp || v:version < 702 || (exists('g:loaded_airline') && g:loaded_airline)
|
||
finish
|
||
endif
|
||
let g:loaded_airline = 1
|
||
function! s:check_defined(variable, default)
|
||
if !exists(a:variable)
|
||
let {a:variable} = a:default
|
||
endif
|
||
endfunction
|
||
if exists('g:airline_enable_fugitive') || exists('g:airline_fugitive_prefix')
|
||
echom 'The g:airline_enable_fugitive and g:airline_fugitive_prefix variables have been deprecated and renamed to g:airline_enable_branch and g:airline_branch_prefix respectively. Please update your vimrc.'
|
||
endif
|
||
if exists('g:airline_window_override_funcrefs')
|
||
echom 'The g:airline_window_override_funcrefs variable has been deprecated. Please use g:airline_statusline_funcrefs instead.'
|
||
endif
|
||
call s:check_defined('g:airline_left_sep', exists('g:airline_powerline_fonts')?"":">")
|
||
call s:check_defined('g:airline_left_alt_sep', exists('g:airline_powerline_fonts')?"":">")
|
||
call s:check_defined('g:airline_right_sep', exists('g:airline_powerline_fonts')?"":"<")
|
||
call s:check_defined('g:airline_right_alt_sep', exists('g:airline_powerline_fonts')?"":"<")
|
||
call s:check_defined('g:airline_enable_bufferline', 1)
|
||
call s:check_defined('g:airline_enable_branch', 1)
|
||
call s:check_defined('g:airline_enable_syntastic', 1)
|
||
call s:check_defined('g:airline_enable_tagbar', 1)
|
||
call s:check_defined('g:airline_detect_iminsert', 0)
|
||
call s:check_defined('g:airline_detect_modified', 1)
|
||
call s:check_defined('g:airline_detect_paste', 1)
|
||
call s:check_defined('g:airline_branch_prefix', exists('g:airline_powerline_fonts')?' ':'')
|
||
call s:check_defined('g:airline_readonly_symbol', exists('g:airline_powerline_fonts')?'':'RO')
|
||
call s:check_defined('g:airline_linecolumn_prefix', exists('g:airline_powerline_fonts')?' ':':')
|
||
call s:check_defined('g:airline_paste_symbol', (exists('g:airline_powerline_fonts') ? ' ' : '').'PASTE')
|
||
call s:check_defined('g:airline_theme', 'dark')
|
||
call s:check_defined('g:airline_exclude_filenames', ['DebuggerWatch','DebuggerStack','DebuggerStatus'])
|
||
call s:check_defined('g:airline_exclude_filetypes', [])
|
||
call s:check_defined('g:airline_exclude_preview', 0)
|
||
call s:check_defined('g:airline_statusline_funcrefs', [])
|
||
call s:check_defined('g:airline_exclude_funcrefs', [])
|
||
|
||
call s:check_defined('g:airline_mode_map', {
|
||
\ 'n' : 'NORMAL',
|
||
\ 'i' : 'INSERT',
|
||
\ 'R' : 'REPLACE',
|
||
\ 'v' : 'VISUAL',
|
||
\ 'V' : 'V-LINE',
|
||
\ 'c' : 'CMD ',
|
||
\ '' : 'V-BLOCK',
|
||
\ })
|
||
|
||
let s:airline_initialized = 0
|
||
let s:active_winnr = -1
|
||
function! s:on_window_changed()
|
||
let s:active_winnr = winnr()
|
||
if !s:airline_initialized
|
||
call airline#extensions#load()
|
||
call airline#load_theme(g:airline_theme)
|
||
call s:check_defined('g:airline_section_a', '%{g:airline_current_mode_text}')
|
||
call s:check_defined('g:airline_section_b', '%{g:airline_externals_branch}')
|
||
call s:check_defined('g:airline_section_c', '%f%m')
|
||
call s:check_defined('g:airline_section_gutter', '')
|
||
call s:check_defined('g:airline_section_x', g:airline_externals_tagbar."%{strlen(&filetype)>0?&filetype:''}")
|
||
call s:check_defined('g:airline_section_y', "%{strlen(&fenc)>0?&fenc:''}%{strlen(&ff)>0?'['.&ff.']':''}")
|
||
call s:check_defined('g:airline_section_z', '%3p%% '.g:airline_linecolumn_prefix.'%3l:%3c')
|
||
let s:airline_initialized = 1
|
||
endif
|
||
call airline#update_statusline()
|
||
endfunction
|
||
|
||
" non-trivial number of external plugins use eventignore=all, so we need to account for that
|
||
function! s:sync_active_winnr()
|
||
if winnr() != s:active_winnr
|
||
" prevent ctrlp statusline from getting overwritten
|
||
if get(g:, 'loaded_ctrlp', 0) && match(&statusline, 'CtrlPlight') >= 0
|
||
return
|
||
endif
|
||
call s:on_window_changed()
|
||
endif
|
||
endfunction
|
||
|
||
function! s:get_airline_themes(a, l, p)
|
||
let files = split(globpath(&rtp, 'autoload/airline/themes/'.a:a.'*'), "\n")
|
||
return map(files, 'fnamemodify(v:val, ":t:r")')
|
||
endfunction
|
||
function! s:airline_theme(...)
|
||
if a:0
|
||
call airline#load_theme(a:1)
|
||
else
|
||
echo g:airline_theme
|
||
endif
|
||
endfunction
|
||
command! -nargs=? -complete=customlist,<sid>get_airline_themes AirlineTheme call <sid>airline_theme(<f-args>)
|
||
|
||
augroup airline
|
||
autocmd!
|
||
autocmd ColorScheme * call airline#highlight(['normal'])
|
||
autocmd WinEnter,BufWinEnter,FileType,BufUnload,ShellCmdPost *
|
||
\ call <sid>on_window_changed()
|
||
autocmd CursorMoved * call <sid>sync_active_winnr()
|
||
augroup END
|